修正前

//銀教追加イベント案：カリスマ
//概要：本拠地にランダムで模造銀装兵配備、または寄付金による収入が発生する。
if(Random(3) && KuniFlag[11])
{
	set a,Random(2)
	set b,BaseArea[11]
	set c,Random(41)
	Plus c,10
	if (AreaButaiKz[b]==20)
	{
		set a,1
	}
	if(KuniPlayer[11])
	{
		if (a==1)
		{
			Window 0
			Size 356,96
			Print 信者から寄付金が届けられました。
			PrintKz c
			Print Leyの臨時収入を得ました。
			WindowOn 0
		}
		if (a==0)
		{
			Window 0
			Size 356,96
			Print 熱烈な信者が、
			Print 志願兵として本拠地の部隊に合流しました。
			WindowOn 1
			Window 1
			Size 356,96
			FaceOut %模造銀装兵A
			//ここの部分は専用のユニットをあてがっても面白いかなぁ
			WindowOn 0
		}
	}
	if (a==1)
	{
		Plus Ley[11],c
	}
	if (a==0)
	{
		CharSet b,%模造銀装兵A
	}
}

問題点
・if(Random(3))　→　if(Random(3)==0)
（==0　等の指定がない場合は、0以外を成立とします。
　Random(x)は0〜x-1を出す命令なので、三分の一ではなくて、三分の二の確率で発生する仕様です。
・set x,y　→　Set x,y
（大文字と小文字の間違いは致命的です。エラーが出て正常に動作しないのです
　ＵＰ前に、一度でも動作確認をしていれば分かるミスです……(汗）
・a==1　a==0 両方に　Window 0
（スクリプト削減のために、流用できる箇所は流用しよう）
・WindowOff忘れ

修正後

//銀教追加イベント案：カリスマ
//概要：本拠地にランダムで模造銀装兵配備、または寄付金による収入が発生する。
if(Random(3)==0 && KuniFlag[11])
{
	Set a,Random(2)
	Set b,BaseArea[11]
	Set c,Random(41)
	Plus c,10
	if (AreaButaiKz[b]==20)
	{
		Set a,1
	}
	if(KuniPlayer[11])
	{
		Window 0
		Size 356,96
		if (a==1)
		{
			Print 信者から寄付金が届けられました。
			PrintKz c
			Print Leyの臨時収入を得ました。
		}
		if (a==0)
		{
			Print 熱烈な信者が、
			Print 志願兵として本拠地の部隊に合流しました。
			WindowOn 1
			Window 1
			Size 356,96
			FaceOut %模造銀装兵A
			//ここの部分は専用のユニットをあてがっても面白いかなぁ
		}
		WindowOn 0
		WindowOff
	}
	if (a==1)
	{
		Plus Ley[11],c
	}
	if (a==0)
	{
		CharSet b,%模造銀装兵A
	}
}